Usage: @ <variable name> <assignment operator> <value>

  The @ command is a special form of ASSIGN.  It is designed mainly for
  mathematical operations, but in truth can be used almost anywhere that
  ASSIGN can.  This command cannot be used from the input line in
  ircII.  Its use is limited to within ircII scripts.  It is generally used
  in place of the ${} structure.  So instead of doing something like

    ASSIGN var1 1
    ASSIGN var2 ${var1 + 1}

  you would use

    @ var1 = 1
    @ var2 = [$var1] + 1

  which is a bit easier to read and makes more sense mathematically.  If
  the brackets [] are used, variables and functions must be prepended with
  the ``$'', otherwise the variable will not expand the assigned <value>
  and will instead be given the literal text.

  The @ can also be effectively used for text processing.  Something
  like

    @ var1 = [foo]
    @ var2 = [bar]
    @ fubar = [$var1] ## [$var2]

  would set $fubar to ``foobar''.  The ## is the concatenation operator.
  Though it looks like a comment (#), it has this special meaning when
  used in an @ assignment.

  To remove a variable with @, simple assign it to nothing:

    @ somevar = []

  EPIC increases the functionalityi of @ by way of additional operators
  that may be used.  Most all of the operators present in C/C++ may be used
  in EPIC scripts and will function in a similar if not like manner:

    Assignment Operators
    =, +=, -=, *=, /=, %=, &=, |=, ^=, #=, ``,'' [comma operator]

    Arithmetic Operators
    +, -, *, /, %, &, |, ^, ~, ##, ?:

    [In|De]crement Operators
    ++, --

  So, something like

    @ var1 = [$var1] + 1

  is the same as both of the following:

    @ var1 += 1
    @ var1++

  Also, as in C, spaces between operators and assignments are optional.  So

    @var1=20

  is the same as

    @ var1 = 20

  Neither is wrong or right, use whichever you are most comfortable with.
  See the operator Parse Tree in expressions for the operator precedence
  rules.

See Also:
  ALIAS functions
  ASSIGN
  expressions
